[moveItemAtPath]リネーム

リネームもこの方法が断然シンプル
これからこの方法にしよ♪

---

#!/usr/bin/env osascript

----+----1----+----2----+-----3----+----4----+----5----+----6----+----7

#

#

#

#

# com.cocolog-nifty.quicktimer.icefloe

----+----1----+----2----+-----3----+----4----+----5----+----6----+----7

use AppleScript version "2.8"

use framework "Foundation"

use scripting additions

property objMe : a reference to current application

property objNSString : a reference to objMe's NSString

set objFileManager to objMe's NSFileManager's defaultManager()

#####テキストの内容

###現在使用中のフォアグラウンドアプリケーション名一覧

tell application "System Events"

set listAppList to name of (processes where background only is false)

end tell

set strAppList to ""

repeat with objAppList in listAppList

set strAppName to objAppList as text

set strAppList to (strAppList & strAppName & "\n") as text

end repeat

###NSStringテキスト

set objAppList to objNSString's stringWithString:strAppList

######################

###フォルダのパス

###デスクトップフォルダのパス

set aliasDirPath to (path to desktop folder from user domain) as alias

set strDirPath to POSIX path of aliasDirPath as text

####

##まず最初に作るファイルのファイル名

set strNerFileName to "NewFile.txt"

set strNerFilePath to ("" & strDirPath & strNerFileName & "") as text

###NSStringテキスト

set objNerFilePath to objNSString's stringWithString:strNerFilePath

###ファイルを作る

set boolMakeNewFile to (objFileManager's createFileAtPath:objNerFilePath |contents|:objAppList attributes:(missing value))

log boolMakeNewFile

###ここでデスクトップにNewFile.txtが出来上がる

####確認するときはRetuneしてみて

#return

####移動先のファイル名

set strDateAndTimeJp to (my dateFormatterWithFormat:"yyyy年MMMMdd日EEEE")

set strDistFilePath to ("" & strDirPath & strDateAndTimeJp & ".txt")

###NSStringテキスト

set objDistFilePath to objNSString's stringWithString:strDistFilePath

###ファイルを移動する(この場合はリネーム）

set boolMoveFileAndRename to (objFileManager's moveItemAtPath:objNerFilePath toPath:objDistFilePath |error|:(missing value))

log boolMoveFileAndRename

-->true or false

###日付のサブ

on dateFormatterWithFormat:classDateFormat

set formatter to objMe's NSDateFormatter's alloc()'s init()

formatter's setLocale:(objMe's NSLocale's localeWithLocaleIdentifier:"ja_JP_POSIX")

formatter's setDateFormat:(classDateFormat as string)

set theString to (formatter's stringFromDate:(current date)) as text

end dateFormatterWithFormat: