[Plist]mobileconfigはPropertyListです

２回目
ブランクのmobileconfigを作成します

---

#!/usr/bin/env osascript

----+----1----+----2----+-----3----+----4----+----5----+----6----+----7

#

#

#

#

# com.cocolog-nifty.quicktimer.icefloe

----+----1----+----2----+-----3----+----4----+----5----+----6----+----7

##自分環境がos12なので2.8にしているだけです

use AppleScript version "2.8"

use framework "Foundation"

use scripting additions

property refMe : a reference to current application

###設定項目　

set strDomain to "com.cocolog-nifty.quicktimer"

####################################

#### ファイルパス関連　保存先

####################################

###デスクトップに空のplistを作成

set strFilePath to ("~/Desktop/com.smaple.test.mobileconfig")

###NSStringにして

set ocidPosixPath to refMe's NSString's stringWithString:strFilePath

##NSStringフルパスにして

set ocidFilePath to ocidPosixPath's stringByStandardizingPath

set ocidFilePathURL to refMe's NSURL's alloc()'s initFileURLWithPath:ocidFilePath isDirectory:false

####################################

#### NSMutableDictionary可変ディレクトリ

####################################

set ocidPlistData to refMe's NSMutableDictionary's alloc()'s initWithCapacity:0

###boolean 項目の 設定

-->false

set ocidFalse to (refMe's NSNumber's numberWithBool:false)

-->true

set ocidTrue to (refMe's NSNumber's numberWithBool:true)

####################################

#### PayloadContent項目

####################################

set ocidPayloadContentArray to refMe's NSMutableArray's alloc()'s initWithCapacity:0

(*

ここにPayloadContentの内容を記載

*)

####################################

#### ROOT項目

####################################

####PayloadContent

ocidPlistData's setObject:(ocidPayloadContentArray) forKey:"PayloadContent"

##################integer

###PayloadVersion

ocidPlistData's setObject:(1 as integer) forKey:"PayloadVersion"

###TargetDeviceType 0=any 5=mac

ocidPlistData's setObject:(0 as integer) forKey:"TargetDeviceType"

##################string

###PayloadUUID

set ocidConcreteUUID to refMe's NSUUID's UUID()

set ocidUUIDString to ocidConcreteUUID's UUIDString()

set strUUIDString to ocidUUIDString as string

ocidPlistData's setObject:(strUUIDString) forKey:"PayloadUUID"

###PayloadIdentifier

set ocidConcreteUUID to refMe's NSUUID's UUID()

set ocidUUIDString to ocidConcreteUUID's UUIDString()

set strUUIDString to strDomain & "." & ocidUUIDString as string

ocidPlistData's setObject:(strUUIDString) forKey:"PayloadIdentifier"

###PayloadType これは固定

ocidPlistData's setObject:("Configuration" as string) forKey:"PayloadType"

###PayloadScope User or System

ocidPlistData's setObject:("User" as string) forKey:"PayloadScope"

###PayloadDisplayName

ocidPlistData's setObject:("Wifi設定" as string) forKey:"PayloadDisplayName"

###PayloadDescription

ocidPlistData's setObject:("Wifi設定です。削除可能です" as string) forKey:"PayloadDescription"

##################Record

###ConsentText

set recorConsentText to {default:"Wifi設定のみ行います"} as record

ocidPlistData's setObject:{recorConsentText} forKey:"ConsentText"

##################BOOL

###削除可非

ocidPlistData's setObject:(ocidTrue) forKey:"PayloadRemovalDisallowed"

###パスワード指定

ocidPlistData's setObject:(ocidFalse) forKey:"HasRemovalPasscode"

####################################

#### PLIST形式に変換

####################################

####XMLフォーマット

set ocidPlistFotmat to refMe's NSPropertyListXMLFormat_v1_0

####PLIST形式に変換

set lisrResponse to refMe's NSPropertyListSerialization's dataWithPropertyList:ocidPlistData format:ocidPlistFotmat options:0 |error|:(reference)

####取り出し

set ocidPlistOutPutData to (item 1 of lisrResponse)

####################################

#### 保存

####################################

#####書き込み

set boolMakeQrCode to (ocidPlistOutPutData's writeToURL:ocidFilePathURL options:(refMe's NSDataWritingAtomic) |error|:(reference))