« TSV2AdobeXML タブ区切りテキストからAdobe Illustratorの変数印字用の『変数ライブラリ』を生成する(1ページに複数面付け版) | トップページ | [NSPasteboard]ファイルパス ファイルURL »

Microsoft Fontsダウンロード


【スクリプトエディタで開く】|

#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
# com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions
property refMe : a reference to current application



set strURL to ("https://go.microsoft.com/fwlink/?linkid=525136") as text

################################
#ファイルのダウンロード先
#起動時に削除される項目
set appFileManager to refMe's NSFileManager's defaultManager()
set ocidTempDirURL to appFileManager's temporaryDirectory()
set ocidUUID to refMe's NSUUID's alloc()'s init()
set ocidUUIDString to ocidUUID's UUIDString
set ocidSaveDirPathURL to ocidTempDirURL's URLByAppendingPathComponent:(ocidUUIDString) isDirectory:true
#フォルダ生成
set ocidAttrDict to refMe's NSMutableDictionary's alloc()'s initWithCapacity:0
ocidAttrDict's setValue:(511) forKey:(refMe's NSFilePosixPermissions)
set listBoolMakeDir to appFileManager's createDirectoryAtURL:(ocidSaveDirPathURL) withIntermediateDirectories:true attributes:(ocidAttrDict) |error|:(reference)
#リダイレクト先のURLを取得
set strCommandText to ("/usr/bin/curl -s -L -I -o /dev/null -w '%{url_effective}' \"" & strURL & "\"") as text
set strURL to (do shell script strCommandText) as text
################################
set ocidURLString to refMe's NSString's stringWithString:(strURL)
set ocidURL to refMe's NSURL's alloc()'s initWithString:(ocidURLString)
#リダイレクト先のURLからダウンロードファイル名
set ocidFileName to ocidURL's lastPathComponent() as text
#ダウンロード先URLからパス
set ocidSaveFilePathURL to ocidSaveDirPathURL's URLByAppendingPathComponent:(ocidFileName)
set strSaveFilePath to ocidSaveFilePathURL's |path| as text
#ファイルダウンロード
set strCommandText to ("/usr/bin/curl -L -o \"" & strSaveFilePath & "\" \"" & strURL & "\" --http1.1 --connect-timeout 20") as text
set strResponse to (do shell script strCommandText) as text
################################
#PKGの解凍先ディレクトリ
set ocidExpandDirPathURL to ocidSaveDirPathURL's URLByAppendingPathComponent:("expand")
set strExpandDirPath to ocidExpandDirPathURL's |path| as text
#ダウンロードしたPKGの解凍
set theComandText to "/usr/sbin/pkgutil --expand \"" & strSaveFilePath & "\" \"" & strExpandDirPath & "\"" as text
do shell script theComandText
################################
#解凍するPayloadのURL
set ocidPayloadFilePathURL to ocidExpandDirPathURL's URLByAppendingPathComponent:("Microsoft_PowerPoint.pkg/Payload")
#Payloadを解凍する解凍先URL
set ocidPayloadExpandDirPathURL to ocidSaveDirPathURL's URLByAppendingPathComponent:("Payload")
#解凍するPayloadのパス
set strPayloadFilePath to ocidPayloadFilePathURL's |path| as text
#解凍先のディレクトリ
set strPayloadExpandFilePath to ocidPayloadExpandDirPathURL's |path| as text
#Payloadの解凍
set theComandText to ("/usr/bin/ditto -xz \"" & strPayloadFilePath & "\" \"" & strPayloadExpandFilePath & "\"") as text
do shell script theComandText
################################
#解凍されたPayloadのフォントディレクトリ
set ocidDFontsDirPathURL to ocidPayloadExpandDirPathURL's URLByAppendingPathComponent:("Microsoft PowerPoint.app/Contents/Resources/DFonts")
#ユーザーのライブラリディレクトリ
set ocidURLsArray to (appFileManager's URLsForDirectory:(refMe's NSLibraryDirectory) inDomains:(refMe's NSUserDomainMask))
set ocidLibraryDirPathURL to ocidURLsArray's firstObject()
#解凍したDFontsの移動先
set ocidDistDirPathURL to ocidLibraryDirPathURL's URLByAppendingPathComponent:("Fonts/Microsoft Fonts")
#DFontsをユーザーのFontsフォルダへ移動
set listDone to appFileManager's moveItemAtURL:(ocidDFontsDirPathURL) toURL:(ocidDistDirPathURL) |error|:(reference)
return

|

« TSV2AdobeXML タブ区切りテキストからAdobe Illustratorの変数印字用の『変数ライブラリ』を生成する(1ページに複数面付け版) | トップページ | [NSPasteboard]ファイルパス ファイルURL »

AppleScript Microsoft」カテゴリの記事