AppleScript Automator

[Automator]script2Applescript スクリプトをテキスト形式にする(修正 パスのエスケープ処理を追加)

ダウンロード - scpt2applescript.zip


【スクリプトエディタで開く】|

on run {argFileInput}
  set numCntSelectedObject to (count of argFileInput) as integer
  if numCntSelectedObject = 0 then
return "未選択です"
  end if
  repeat with itemFilePath in argFileInput
    set aliasFilePath to itemFilePath as alias
    set objInfo to get info for aliasFilePath
    if (folder of objInfo) is true then
log "フォルダなので処理しない"
    else if (type identifier of objInfo) is "com.apple.applescript.text" then
log "すでにテキスト形式なので処理しない"
    else if (type identifier of objInfo) is "com.apple.applescript.script" then
      set strExtension to name extension of objInfo
      set strNewExtension to "applescript"
      set strName to (name of objInfo) as text
      tell application "Finder"
        set aliasSaveDirPath to (container of aliasFilePath) as alias
        set strSaveDirPath to POSIX path of aliasSaveDirPath as text
      end tell
      set strFilePath to POSIX path of aliasFilePath as text
      set strSaveFilePath to doReplace(strFilePath, ".scpt", ".applescript") as text
      set aliasSavePath to POSIX file strSaveFilePath as «class furl»
      #別名保存
      tell application "Script Editor"
open aliasFilePath
save the front document as "text" in aliasSavePath
close front document
      end tell
      ##エスケープ エラーよけ
      set strSaveFilePath to doReplace(strSaveFilePath, "\"", "\\\"")
      set strSaveFilePath to doReplace(strSaveFilePath, "'", "\\'")
      set theComandText to ("chmod 755 \"" & strSaveFilePath & "\"") as text
do shell script theComandText
      #スクリプトはゴミ箱へ
      tell application "Finder"
move aliasFilePath to trash
      end tell
    else
log "スクリプト形式以外は処理しない"
    end if
  end repeat
end run


##文字列置換
to doReplace(theText, orgStr, newStr)
  set oldDelim to AppleScript's text item delimiters
  set AppleScript's text item delimiters to orgStr
  set tmpList to every text item of theText
  set AppleScript's text item delimiters to newStr
  set tmpStr to tmpList as text
  set AppleScript's text item delimiters to oldDelim
return tmpStr
end doReplace

|

[Automator]WeblocファイルからURLをコピーする

ダウンロード - webloc2clipboard.zip


【スクリプトエディタで開く】|

#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
#com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
use AppleScript version "2.8"
use framework "Foundation"
use framework "UniformTypeIdentifiers"
use framework "AppKit"
use scripting additions
property refMe : a reference to current application
property strBundleID : "com.apple.Safari" as text


on run {argAliasFilePath, parameters}
  
  ##ファイルパス
  set strFilePath to (POSIX path of argAliasFilePath) as text
  set ocidFilePathStr to refMe's NSString's stringWithString:(strFilePath)
  set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
  set ocidFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:(ocidFilePath) isDirectory:false)
  ##読み込み
  set ocidPlistDict to refMe's NSMutableDictionary's alloc()'s initWithContentsOfURL:(ocidFilePathURL)
  #値の取得
  set ocidURL to ocidPlistDict's valueForKey:("URL")
  set strResponseText to ocidURL as text
  ########################
  ##ダイアログ
  ########################
  set aliasIconPath to POSIX file "/System/Library/CoreServices/CoreTypes.bundle/Contents/Resources/AlertNoteIcon.icns" as alias
  
  #前面に
  set strName to (name of current application) as text
  if strName is "osascript" then
    tell application "Finder" to activate
  else
    tell current application to activate
  end if
  #
  set strTitle to ("戻り値です") as text
  set strMes to ("戻り値です
値のコピーができます") as text
  set recordResult to (display dialog strMes with title strTitle default answer strResponseText buttons {"クリップボードにコピー", "キャンセル", "OK"} default button "OK" giving up after 30 with icon aliasIconPath without hidden answer)
  if (gave up of recordResult) is true then
return "時間切れです"
  else if (button returned of recordResult) is "キャンセル" then
return "キャンセルです"
  else if button returned of recordResult is "クリップボードにコピー" then
    set strReturnedText to (text returned of recordResult) as text
    set aliasIconPath to POSIX file "/System/Library/CoreServices/CoreTypes.bundle/Contents/Resources/AlertNoteIcon.icns"
    set appPasteboard to refMe's NSPasteboard's generalPasteboard()
    set ocidText to (refMe's NSString's stringWithString:(strReturnedText))
appPasteboard's clearContents()
    set boolDone to appPasteboard's setString:(ocidText) forType:(refMe's NSPasteboardTypeString)
    if boolDone = false then
      try
        tell application "Finder"
          set the clipboard to strReturnedText as text
        end tell
      on error
return false
      end try
    else if boolDone = true then
return true
    end if
    
    if boolDone is false then
log ("ペーストボードへのコピーに失敗しました") as text
return "ペーストボードへのコピーに失敗しました"
    end if
  else
log (text returned of recordResult) as text
  end if
  
end run


|

[workflow]ミュージックファイルの曲名とアーティスト名をコピーする

ダウンロード - copy2songtitle.workflow.zip


【スクリプトエディタで開く】|

#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
#com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
use AppleScript version "2.8"
use framework "Foundation"
use framework "AVFoundation"
use framework "AppKit"
use framework "CoreMedia"
use scripting additions
property refMe : a reference to current application


on run ({argListFilePath, argScript})
  set strDefaultAnswer to "" as text
  set numCntFile to (count of argListFilePath) as integer
  set numCnt to 1 as integer
  repeat with itemAliasFilePath in argListFilePath
    ###パス
    set strFilePath to (POSIX path of itemAliasFilePath) as text
    set ocidFilePath to (refMe's NSString's stringWithString:strFilePath)
    set ocidFilePath to ocidFilePath's stringByExpandingTildeInPath()
    set ocidFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:ocidFilePath isDirectory:false)
    ##
    set strArtist to doGetArtistName(ocidFilePathURL) as text
    set strTitle to doGetTitle(ocidFilePathURL) as text
    if numCntFile = 1 then
      set strDefaultAnswer to (strTitle & " - " & strArtist) as text
    else if numCntFile = numCnt then
      set strDefaultAnswer to (strDefaultAnswer & (strTitle & " - " & strArtist)) as text
    else
      set strDefaultAnswer to (strDefaultAnswer & (strTitle & " - " & strArtist) & "
") as text
    end if
    set numCnt to numCnt + 1 as integer
  end repeat
  ##############################
  #####ダイアログ
  ##############################
  ##前面に出す
  set strName to (name of current application) as text
  if strName is "osascript" then
    tell application "Finder" to activate
  else
    tell current application to activate
  end if
  ###アイコンパス
  set aliasIconPath to POSIX file "/System/Applications/Music.app/Contents/Resources/AppIcon.icns" as alias
  set strMes to (strDefaultAnswer) as text
  set recordResult to (display dialog strMes with title "選んでください" default answer strDefaultAnswer buttons {"クリップボードにコピー", "キャンセル", "OK"} default button "OK" cancel button "キャンセル" giving up after 20 with icon aliasIconPath without hidden answer)
  ###クリップボードコピー
  if button returned of recordResult is "クリップボードにコピー" then
    set strText to (text returned of recordResult) as text
    try
      ####ペーストボード宣言
      set appPasteboard to refMe's NSPasteboard's generalPasteboard()
      set ocidText to (refMe's NSString's stringWithString:(strText))
appPasteboard's clearContents()
appPasteboard's setString:(ocidText) forType:(refMe's NSPasteboardTypeString)
    on error
      tell application "Finder"
        set the clipboard to strText as text
      end tell
    end try
  end if
end run

###########################################
### アーティスト名を読み取るサブ
###########################################

to doGetArtistName(argURL)
  ###URLアセットを取得
  set ocidAVURLAsset to refMe's AVURLAsset's URLAssetWithURL:argURL options:(missing value)
  ###メタデータを取得
  set ocidCommonMetadata to ocidAVURLAsset's commonMetadata()
  ###AVMetadataCommonKeyArtistメタデータを取得
  set ocidTitleArray to refMe's AVMetadataItem's metadataItemsFromArray:ocidCommonMetadata withKey:(refMe's AVMetadataCommonKeyArtist) keySpace:(refMe's AVMetadataKeySpaceCommon)
  set ocidMetaArtist to ocidTitleArray's objectAtIndex:0
  set strMetaArtist to ocidMetaArtist's |value|() as text
return (strMetaArtist)
end doGetArtistName

###########################################
### タイトルを読み取る
###########################################
to doGetTitle(argURL)
  ###URLアセットを取得
  set ocidAVURLAsset to refMe's AVURLAsset's URLAssetWithURL:argURL options:(missing value)
  ###メタデータを取得
  set ocidCommonMetadata to ocidAVURLAsset's commonMetadata()
  ###AVMetadataCommonKeyTitleメタデータを取得
  set ocidTitleArray to refMe's AVMetadataItem's metadataItemsFromArray:ocidCommonMetadata withKey:(refMe's AVMetadataCommonKeyTitle) keySpace:(refMe's AVMetadataKeySpaceCommon)
  set ocidMetaTitle to ocidTitleArray's objectAtIndex:0
  set strTitle to ocidMetaTitle's |value|() as text
return (strTitle)
end doGetTitle

|

[Automator]Adobe Bridge 2024で開く

ダウンロード - openbridge14.workflow.zip


【スクリプトエディタで開く】|

#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
# Automator ワークフロー用 (クイックアクション)
# ワークフローが受け取るのは『フォルダ』 アプリケーションは『Finder』
# com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
use AppleScript version "2.8"
use framework "Foundation"
use framework "UniformTypeIdentifiers"
use scripting additions

on run {input}
  set strBundleID to "com.adobe.bridge14" as text
  ####フォルダの数だけ繰り返し
  repeat with itemFolderPath in input
    ######パス フォルダのエイリアス
    set aliasDirPath to itemFolderPath as alias
    ###入力のフォルダのエイリアスをアプリで開く
    tell application id strBundleID to launch
    tell application id strBundleID
      open aliasDirPath
    end tell
  end repeat
end run

|

[workflow用]イメージピクセルサイズのCSSをクリップボードにコピー


【スクリプトエディタで開く】|

use AppleScript version "2.8"
use scripting additions
use framework "Foundation"
use framework "AppKit"
property refMe : a reference to current application


property numYpx : 0
property numXpx : 0

on run {argAliasFilePath}
  set strFilePath to (POSIX path of argAliasFilePath) as text
  set ocidFilePathStr to refMe's NSString's stringWithString:(strFilePath)
  set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
  set objImageRep to (refMe's NSBitmapImageRep's imageRepWithContentsOfFile:(ocidFilePath))
  tell objImageRep
    set numXpx to pixelsHigh()
    set numYpx to pixelsWide()
  end tell
  set strResponse to "width:" & numYpx & "px;height:" & numXpx & "px;" as text
  set the clipboard to strResponse as text
end run

|

[workflow用]イメージの縦横ピクセルサイズでリネーム

ダウンロード - image2.zip


【スクリプトエディタで開く】|

use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions
property refMe : a reference to current application


property numYpx : 0
property numXpx : 0


on run {argAliasFilePath}
  set strFilePath to (POSIX path of argAliasFilePath) as text
  set ocidFilePathStr to refMe's NSString's stringWithString:(strFilePath)
  set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
  set ocidFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:(ocidFilePath) isDirectory:false)
  set strExtensionName to (ocidFilePathURL's pathExtension()) as text
  set ocidFileName to ocidFilePathURL's lastPathComponent()
  set strBaseFileName to (ocidFileName's stringByDeletingPathExtension()) as text
  set ocidContainerDirPathURL to ocidFilePathURL's URLByDeletingLastPathComponent()
  set objImageRep to (refMe's NSBitmapImageRep's imageRepWithContentsOfURL:(ocidFilePathURL))
  tell objImageRep
    set numHpx to pixelsHigh()
    set numWpx to pixelsWide()
  end tell
  set objImageRep to ""
  set strNewFileName to (strBaseFileName & "." & numWpx & "x" & numHpx & "." & strExtensionName) as text
  set ocidNewFilePathURL to ocidContainerDirPathURL's URLByAppendingPathComponent:(strNewFileName)
  set appFileManager to refMe's NSFileManager's defaultManager()
  set listDone to appFileManager's moveItemAtURL:(ocidFilePathURL) toURL:(ocidNewFilePathURL) |error|:(reference)
end run

|

[workflow]選択ファイルを実行する

ダウンロード - doshellscript.workflow.zip


【スクリプトエディタで開く】|

use AppleScript version "2.8"
use scripting additions

tell application "Finder" to activate

###対象は選択中のファイル
tell application "Finder"
  set listAliasPath to selection as list
end tell

repeat with itemAliasFilePath in listAliasPath
  set aliasAliasFilePath to itemAliasFilePath as alias
  tell application "Finder"
    set strKind to kind of aliasAliasFilePath
    if strKind is "フォルダ" then
return "フォルダは処理しない"
    end if
    set strExtension to name extension of aliasAliasFilePath
    if strExtension is "applescript" then
      log "applescript"
    else if strExtension is "bash" then
      log "bash"
    else if strExtension is "command" then
      log "command"
    else if strExtension is "sh" then
      log "sh"
    else
return "対象ファイル以外は処理しない"
    end if
    
  end tell
  set strFilePath to (POSIX path of aliasAliasFilePath) as text
  set strCommandText to ("\"" & strFilePath & "\"") as text
  do shell script strCommandText
end repeat

|

[workflow] mobileconfigを開く

ダウンロード -Openモバイルコンフィグ.workflow.zip


【スクリプトエディタで開く】|

on run {input}
  tell application "System Settings" to launch
  --システム環境設定が開くのを待つ
  repeat
    set doLaunchApp to get running of application "System Settings"
    if doLaunchApp is false then
      delay 0.5
    else
      exit repeat
    end if
  end repeat
  try
    set strCommandText to "open -b com.apple.systempreferences \"/System/Library/PreferencePanes/Profiles.prefPane\"" as text
    do shell script strCommandText
  on error
    tell application id "com.apple.systempreferences"
      activate
reveal anchor "Main" of pane id "com.apple.Profiles-Settings.extension"
    end tell
  end try
  repeat 10 times
    tell application id "com.apple.systempreferences"
      activate
reveal anchor "Main" of pane id "com.apple.Profiles-Settings.extension"
      tell current pane
set strPaneID to id as text
properties
      end tell
    end tell
    if strPaneID is "com.apple.settings.PrivacySecurity.extension" then
      exit repeat
    else
      delay 0.5
    end if
  end repeat
  
  tell application "Finder"
    set strFilePath to POSIX path of input
    set theCmdCom to ("open \"" & strFilePath & "\" | open \"x-apple.systempreferences:com.apple.preferences.configurationprofiles\"") as text
    do shell script theCmdCom
  end tell
  
end run


|

画像のPNG変換(ワークフロー用)

ダウンロード - image2png.zip


【スクリプトエディタで開く】|

#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
#オートメーターのワークフロー用
# com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
##自分環境がos12なので2.8にしているだけです
use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use framework "CoreImage"
use scripting additions

property refMe : a reference to current application

on run {input}
  repeat with itemAliasFilePath in input
    ###入力パス
    set strFilePath to POSIX path of itemAliasFilePath
    set ocidFilePathStr to (refMe's NSString's stringWithString:(strFilePath))
    set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
    set ocidFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:ocidFilePath isDirectory:false)
    #####拡張子を取って
    set ocidBaseFilePathURL to ocidFilePathURL's URLByDeletingPathExtension()
    ######新しい拡張子を加える
    set ocidSaveFilePathURL to (ocidFilePathURL's URLByAppendingPathExtension:"png")
    
    ###イメージデータ展開
    set ocidImageRep to (refMe's NSBitmapImageRep's imageRepWithContentsOfURL:(ocidFilePathURL))
    ####NSImageColorSyncProfileData
    set ocidColorSpace to refMe's NSColorSpace's displayP3ColorSpace()
    set ocidColorSpaceData to ocidColorSpace's colorSyncProfile()
    ####NSImageEXIFData
    set ocidEXIFData to (ocidImageRep's valueForProperty:(refMe's NSImageEXIFData))
    
    ####ガンマ値換算 まぁ2.2入れておけば間違い無いか…しらんけど
    set numGamma to (1 / 2.2) as number
    ####propertiesデータレコード整形(PNG用)
    set ocidImageProperties to {NSImageGamma:(numGamma), NSImageEXIFData:(ocidEXIFData), NSImageInterlaced:false, NSImageColorSyncProfileData:(ocidColorSpaceData)} as record
    
    #####PNGデータに変換
    set ocidSaveData to (ocidImageRep's representationUsingType:(refMe's NSBitmapImageFileTypePNG) |properties|:(ocidImageProperties))
    
    set ocidWroteToFileDone to (ocidSaveData's writeToURL:ocidSaveFilePathURL options:0 |error|:(reference))
    
    set ocidSaveData to ""
    set ocidImageRep to ""
    
  end repeat
end run


|

[フォルダアクション]ダウンロードしたURLをファイルコメント入れておく

フォルダアクション用
ZIPファイルの解凍時の処理は考え中


【スクリプトエディタで開く】


on run {argAliasFilePath}
  ###受け取ったファイルパスをエリアスとUNIXパスにしておく
  set strFilePath to (POSIX path of argAliasFilePath) as text
  set aliasFilePath to argAliasFilePath as alias
  ###コマンド整形
  set strCommandText to "/usr/bin/mdls -name \"kMDItemWhereFroms\"  \"" & strFilePath & "\""
  ###コマンド実行
  set strResponse to (do shell script strCommandText) as text
  ###ダブルクオトでリスト化
  set AppleScript's text item delimiters to "\""
  set listResponse to every text item of strResponse
  set AppleScript's text item delimiters to ""
  ###コメントに入れるテキスト初期化
  set strCommentText to "" as text
  ###リストの数だけ繰り返し
  repeat with itemResponse in listResponse
    set strItemResponse to itemResponse as text
    if strItemResponse starts with "http" then
      set strCommentText to strCommentText & strItemResponse & "\r"
    end if
  end repeat
  ########すでに登録されているコメント
  tell application "Finder"
    set strNowComment to (comment of aliasFilePath) as text
  end tell
  ######すでにコメントがある場合は追加する
  if strNowComment is not "" then
    set strCommentText to (strNowComment & "\r" & strCommentText) as text
  end if
  #####コメントをセットする
  tell application "Finder"
    set comment of file aliasFilePath to strCommentText
  end tell
  return
end run

|

その他のカテゴリー

Acrobat Acrobat Annotation Acrobat Dialog Acrobat Form Acrobat JS Acrobat Open Acrobat Plugin Acrobat python Acrobat Reader Acrobat Sequ Acrobat Stamps Admin Admin Account Admin Apachectl Admin configCode Admin Device Management Admin LaunchServices Admin Locationd Admin loginitem Admin Maintenance Admin Permission Admin Pkg Admin Power Management Admin Printer Admin SetUp Admin SMB Admin System Information Admin Tools Admin Users Admin Volumes Adobe Apple AppleScript AppleScript Guide AppleScript Accessibility AppleScript AppKit AppleScript Applications AppleScript AppStore AppleScript Archive AppleScript Attributes AppleScript Automator AppleScript AVAsset AppleScript AVconvert AppleScript AVFoundation AppleScript AVURLAsset AppleScript BackUp AppleScript Barcode AppleScript Bash AppleScript Basic AppleScript Basic Path AppleScript Bluetooth AppleScript BOX AppleScript Browser AppleScript Calendar AppleScript CD/DVD AppleScript Choose AppleScript Chrome AppleScript CIImage AppleScript CloudStorage AppleScript Color AppleScript com.apple.LaunchServices.OpenWith AppleScript Console AppleScript Contacts AppleScript CotEditor AppleScript CURL AppleScript current application AppleScript Date&Time AppleScript delimiters AppleScript Desktop AppleScript Device AppleScript Disk AppleScript do shell script AppleScript Dock AppleScript DropBox AppleScript eMail AppleScript Encode Decode AppleScript Error AppleScript EXIFData AppleScript ffmpeg AppleScript File AppleScript Finder AppleScript Firefox AppleScript Folder AppleScript Fonts AppleScript GIF AppleScript HTML AppleScript Icon AppleScript Illustrator AppleScript Image Events AppleScript Image2PDF AppleScript ImageOptim Applescript iWork AppleScript Javascript AppleScript Jedit AppleScript Json AppleScript Label AppleScript List AppleScript locationd AppleScript LRC AppleScript LSSharedFileList AppleScript m3u8 AppleScript MakePDF AppleScript Map AppleScript Math AppleScript Microsoft AppleScript Microsoft Edge AppleScript Microsoft Excel AppleScript Mobileconfig AppleScript Mouse AppleScript Movie AppleScript Music AppleScript NetWork AppleScript Notes AppleScript NSArray AppleScript NSBitmapImageRep AppleScript NSBundle AppleScript NSCFBoolean AppleScript NSCharacterSet AppleScript NSColor AppleScript NSColorList AppleScript NSData AppleScript NSDictionary AppleScript NSError AppleScript NSEvent AppleScript NSFileAttributes AppleScript NSFileManager AppleScript NSFont AppleScript NSFontManager AppleScript NSImage AppleScript NSIndex AppleScript NSKeyedArchiver AppleScript NSKeyedUnarchiver AppleScript NSLocale AppleScript NSMutableArray AppleScript NSMutableDictionary AppleScript NSMutableString AppleScript NSNotFound AppleScript NSNumber AppleScript NSOpenPanel AppleScript NSPasteboard AppleScript NSPDFImageRep AppleScript NSpoint AppleScript NSPredicate AppleScript NSRange AppleScript NSRegularExpression AppleScript NSRunningApplication AppleScript NSScreen AppleScript NSSize AppleScript NSString AppleScript NSStringCompareOptions AppleScript NSTask AppleScript NSTimeZone AppleScript NSURL AppleScript NSURL File AppleScript NSURLBookmark AppleScript NSURLComponents AppleScript NSURLResourceKey AppleScript NSUserDefaults AppleScript NSUUID AppleScript NSView AppleScript NSWorkspace AppleScript Numbers AppleScript OAuth AppleScript ObjC AppleScript OneDrive AppleScript Osax AppleScript PDF AppleScript PDFAnnotationWidget AppleScript PDFContext AppleScript PDFDisplayBox AppleScript PDFDocumentPermissions AppleScript PDFKit AppleScript PDFnUP AppleScript PDFOutline AppleScript Photos AppleScript Photoshop AppleScript Plist System Events AppleScript PostScript AppleScript prefPane AppleScript Preview AppleScript Python AppleScript QR AppleScript QR Decode AppleScript QuickLook AppleScript QuickTime AppleScript record AppleScript Regular Expression AppleScript Reminders AppleScript ReName AppleScript Repeat AppleScript RTF AppleScript Safari AppleScript SaveFile AppleScript ScreenCapture AppleScript ScreenSaver AppleScript Script Editor AppleScript Script Menu AppleScript Shortcuts AppleScript Shortcuts Events AppleScript Sort AppleScript Sound AppleScript Spotlight AppleScript SRT AppleScript StandardAdditions AppleScript stringByApplyingTransform AppleScript System Events AppleScript System Settings AppleScript TemporaryItems AppleScript Terminal AppleScript Text AppleScript Text CSV AppleScript Text TSV AppleScript TextEdit AppleScript Translate AppleScript Trash AppleScript Twitter AppleScript UI AppleScript Unit Conversion AppleScript UTType AppleScript valueForKeyPath AppleScript Video AppleScript VisionKit AppleScript Visual Studio Code AppleScript webarchive AppleScript webp AppleScript Wifi AppleScript XML AppleScript XML EPUB AppleScript XML OPML AppleScript XML Plist AppleScript XML RSS AppleScript XML SVG AppleScript XML TTML AppleScript XML webloc AppleScript YouTube AppleScript Zero Suppress Applications Barcode OnLine Tools CityCode Design iPhone List Logs lsappinfo Memo Music perl PlistBuddy pluginkit postalcode ReadMe SF Symbols character id SF Symbols Entity sips Skype Slack sqlite TCC Tools Typography Video Wacom zoom