改行コード変更（仮）
もう少しいい方法があるような気がする
#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
(*
com.cocolog-nifty.quicktimer.icefloe
改行コードを調べて 改行コードを変更する
文字コードはUTF-8に変更する
*)
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions
property refMe : a reference to current application
property refNSNotFound : a reference to 9.22337203685477E+18 + 5807
##############################
#設定 デフォルトの改行コード
# 空の場合や
#１行だけで改行の無いテキストの場合
#この改行を適応する
#################################
set listNewLineChar to {"MacCR改行", "UnixLF改行", "WindowsCRLF改行"} as list
###ダイアログを前面に出す
set strName to (name of current application) as text
if strName is "osascript" then
tell application "Finder" to activate
else
tell current application to activate
end if
#
set strTitle to ("選んでください") as text
set strPrompt to ("変更後の保存する改行コードを選んでください\nMac用の場合基本的には\nUnixLF改行を選んでください") as text
try
set listResponse to (choose from list listNewLineChar with title strTitle with prompt strPrompt default items (item 2 of listNewLineChar) OK button name "OK" cancel button name "キャンセル" without multiple selections allowed and empty selection allowed) as list
on error
log "エラーしました"
return "エラーしました"
end try
if (item 1 of listResponse) is false then
return "キャンセルしましたA"
else if (item 1 of listResponse) is {} then
return "キャンセルしましたB"
end if
set strResponse to (item 1 of listResponse) as text
#戻り値をキーにして値＝値を取り出す
if strResponse is "MacCR改行" then
set ocidSetNewLineChar to refMe's NSString's stringWithString:("\r")
else if strResponse is "UnixLF改行" then
set ocidSetNewLineChar to refMe's NSString's stringWithString:("\n")
else if strResponse is "WindowsCRLF改行" then
set ocidSetNewLineChar to refMe's NSString's stringWithString:("\r\n")
end if
##############################
#入力
##############################
#デフォルトロケーション
set appFileManager to refMe's NSFileManager's defaultManager()
set ocidURLsArray to (appFileManager's URLsForDirectory:(refMe's NSDesktopDirectory) inDomains:(refMe's NSUserDomainMask))
set ocidDesktopDirPathURL to ocidURLsArray's firstObject()
set aliasDesktopDirPath to (ocidDesktopDirPathURL's absoluteURL()) as alias
###ダイアログを前面に出す
set strName to (name of current application) as text
if strName is "osascript" then
tell application "Finder" to activate
else
tell current application to activate
end if
#
set listUTI to {"public.text"}
set strMes to ("ファイルを選んでください") as text
set strPrompt to ("テキストファイルを選んでください") as text
try
#ファイル選択
set listFilePath to (choose file strMes with prompt strPrompt default location aliasDesktopDirPath of type listUTI with invisibles, showing package contents and multiple selections allowed) as list
on error
log "エラーしました"
return "エラーしました"
end try
if (item 1 of listFilePath) is false then
return "キャンセルしましたA"
else if listFilePath is {} then
return "キャンセルしましたB"
end if
##############################
#保存先
##############################
#保存先用にユーザーが選択したファイルの最初のエイリアスを取得
set aliasFirstFilePath to (item 1 of listFilePath) as alias
#パスにして
set strFirstFilePath to (POSIX path of aliasFirstFilePath) as text
set ocidFirstFilePathStr to (refMe's NSString's stringWithString:(strFirstFilePath))
set ocidFirstFilePath to ocidFirstFilePathStr's stringByStandardizingPath()
set ocidFirstFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:(ocidFirstFilePath) isDirectory:false)
#ファイルの親階層ディレクトリを取得して
set ocidContainerDirPathURL to ocidFirstFilePathURL's URLByDeletingLastPathComponent()
#エイリアスとしてダイアログに渡す
set aliasContainerDirPath to (ocidContainerDirPathURL's absoluteURL()) as alias
#
set strMes to "フォルダを選んでください" as text
set strPrompt to "フォルダを選択してください\n入力フォルダと同じフォルダを選択すると\n『上書き』になります" as text
try
###ダイアログを前面に出す
set strName to (name of current application) as text
if strName is "osascript" then
tell application "Finder" to activate
else
tell current application to activate
end if
#
set aliasResponse to (choose folder strMes with prompt strPrompt default location aliasContainerDirPath with invisibles and showing package contents without multiple selections allowed) as alias
on error
log "エラーしました"
return "エラーしました"
end try
#戻り値エイリアスをURLに
set strSaveDirPath to (POSIX path of aliasResponse) as text
set ocidSaveDirPathStr to (refMe's NSString's stringWithString:(strSaveDirPath))
set ocidSaveDirPath to ocidSaveDirPathStr's stringByStandardizingPath()
set ocidSaveDirPathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:(ocidSaveDirPath) isDirectory:true)
#上書きチェック
if aliasContainerDirPath = aliasResponse then
log "同じフォルダに保存しようとしています"
set strMes to "上書きを指定しました。\nファイルは上書きになります\nいいですか？" as text
try
###ダイアログを前面に出す
set strName to (name of current application) as text
if strName is "osascript" then
tell application "Finder" to activate
else
tell current application to activate
end if
#
tell application (POSIX path of (path to frontmost application))
set refResponse to (display alert ("【注意】:" & strMes) buttons {"OK", "処理中止"} default button "OK" cancel button "処理中止" as informational giving up after 20)
end tell
on error
log "エラーしました"
return "エラーしました"
error number -128
end try
if true is equal to (gave up of refResponse) then
return "時間切れですやりなおしてください"
error number -128
end if
if "処理中止" is equal to (button returned of refResponse) then
return "処理を中止しました"
end if
end if
##最初のファイル選択で選んだファイルの数だけ繰り返し
repeat with itemAliasFilePath in listFilePath
#入力ファイルパス
set aliasFilePath to itemAliasFilePath as alias
#入力ファイルパス
set strFilePath to (POSIX path of aliasFilePath) as text
set ocidFilePathStr to (refMe's NSString's stringWithString:(strFilePath))
set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
set ocidFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:(ocidFilePath) isDirectory:false)
#ファイル名
set ocidFileName to ocidFilePathURL's lastPathComponent()
set strFileName to ocidFileName as text
#ファイルのテキストを読み込み
set listResponse to (refMe's NSString's alloc()'s initWithContentsOfURL:(ocidFilePathURL) usedEncoding:(refMe's NSUTF8StringEncoding) |error|:(reference))
set ocidReadString to (item 1 of listResponse)
if ocidReadString = (missing value) then
set strFileName to ocidFilePathURL's lastPathComponent() as text
set strMes to ("文字コードを判定出来ませんでした : " & strFileName & "\n処理を中止します") as text
display alert strMes
return
end if
##############################
#改行コード判定
set ocidCrRange to (ocidReadString's rangeOfString:("\r"))'s location()
set ocidLfRange to (ocidReadString's rangeOfString:("\n"))'s location()
if ocidCrRange = refNSNotFound then
log "Mac改行は無い"
if ocidLfRange = refNSNotFound then
log "Mac改行もUNIX改行は無い=改行の無い１行か空のテキスト"
set ocidLength to ocidReadString's |length|
if ocidLength = (refMe's NSNumber's numberWithInteger:0) then
log "空のテキスト"
set ocidNewLineChar to ocidSetNewLineChar
else
log "改行無しの１行テキスト"
set ocidNewLineChar to ocidSetNewLineChar
end if
else
log "Mac改行無＋UNIX改行あり＝UNIX改行"
set ocidNewLineChar to (refMe's NSString's stringWithString:("\n"))
end if
else
if ocidLfRange = refNSNotFound then
log "MacがあるUNIX改行は無い=Mac改行"
set ocidNewLineChar to (refMe's NSString's stringWithString:("\r"))
else
log "Mac改行ある＋UNIX改行あり＝Windows改行"
set ocidNewLineChar to (refMe's NSString's stringWithString:("\r\n"))
end if
end if
##############################
####改行コードを変更
#改行を設定項目の改行コードに変更
set ocidReadCFString to (ocidReadString's stringByReplacingOccurrencesOfString:(ocidNewLineChar) withString:(ocidSetNewLineChar))
#出力先 保存先パス 選んだフォルダ＋ファイル名
set ocidSaveFilePathURL to (ocidSaveDirPathURL's URLByAppendingPathComponent:(ocidFileName))
#保存
set listDone to (ocidReadCFString's writeToURL:(ocidSaveFilePathURL) atomically:(true) encoding:(refMe's NSUTF8StringEncoding) |error|:(reference))
if (item 1 of listDone) is true then
log "保存成功: " & strFileName
else
log "エラーが発生しました: " & strFileName
end if
end repeat
| 固定リンク