[ビデオダウンロード]VOEビデオダウンロード
#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
# com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions
property refMe : a reference to current application
########################
## クリップボードの中身取り出し
########################
##クリップボードにテキストが無い場合
set strMes to ("URLをペーストしてください") as text
###初期化
set ocidPasteboard to refMe's NSPasteboard's generalPasteboard()
set ocidPastBoardTypeArray to ocidPasteboard's types
###テキストがあれば
set boolContain to ocidPastBoardTypeArray's containsObject:"public.utf8-plain-text"
if boolContain = true then
###値を格納する
tell application "Finder"
set strDefaultAnswer to (the clipboard as text) as text
end tell
###Finderでエラーしたら
else
set boolContain to ocidPastBoardTypeArray's containsObject:"NSStringPboardType"
if boolContain = true then
set ocidReadString to ocidPasteboard's readObjectsForClasses:({refMe's NSString}) options:(missing value)
set strDefaultAnswer to ocidReadString as text
else
log "テキストなし"
set strDefaultAnswer to strMes as text
end if
end if
##############################
#####ダイアログ
##############################
set strMes to ("TSファイルのURLをペースト") as text
##前面に出す
set strName to (name of current application) as text
if strName is "osascript" then
tell application "Finder" to activate
else
tell current application to activate
end if
###アイコンパス
set aliasIconPath to POSIX file "/System/Applications/Calculator.app/Contents/Resources/AppIcon.icns" as alias
try
set recordResult to (display dialog strMes with title "入力してください" default answer strDefaultAnswer buttons {"OK", "キャンセル"} default button "OK" with icon aliasIconPath giving up after 20 without hidden answer) as record
on error
log "エラーしました"
return "キャンセル"
end try
if "OK" is equal to (button returned of recordResult) then
set strReturnedText to (text returned of recordResult) as text
else if (gave up of recordResult) is true then
return "時間切れです"
else
return "キャンセル"
end if
##############################
#####URLの分離
##############################
##テキスト
set ocidURLString to refMe's NSMutableString's alloc()'s initWithCapacity:0
ocidURLString's setString:(strReturnedText)
###改行を取る
set ocidCurlLength to ocidURLString's |length|()
set ocidCurlRange to {location:0, |length|:ocidCurlLength}
ocidURLString's replaceOccurrencesOfString:("\n") withString:("") options:(refMe's NSRegularExpressionSearch) range:(ocidCurlRange)
set ocidCurlLength to ocidURLString's |length|()
set ocidCurlRange to {location:0, |length|:ocidCurlLength}
ocidURLString's replaceOccurrencesOfString:("\r") withString:("") options:(refMe's NSRegularExpressionSearch) range:(ocidCurlRange)
##httpならURLコピー
if strReturnedText starts with "http" then
set ocidHeaderText to ("") as text
###CURLならヘッダー付きコピー
else if strReturnedText starts with "curl" then
set ocidCurl to ocidURLString
###『'』でリスト化して２番目がURL
set ocidDelimiters to (refMe's NSCharacterSet)'s characterSetWithCharactersInString:("'")
set ocidURLArray to ocidCurl's componentsSeparatedByCharactersInSet:(ocidDelimiters)
set ocidURLString to ocidURLArray's objectAtIndex:1
###ヘッダー部取り出し
set ocidDelimiters to (refMe's NSCharacterSet)'s characterSetWithCharactersInString:"\\"
set ocidHeaderArray to ocidCurl's componentsSeparatedByCharactersInSet:(ocidDelimiters)
set ocidHeaderArrayLength to ocidHeaderArray's |count|()
set ocidHeaderRange to refMe's NSMakeRange(1, (ocidHeaderArrayLength - 1))
set ocidSubbArray to ocidHeaderArray's subarrayWithRange:(ocidHeaderRange)
set ocidHeaderText to (ocidSubbArray's componentsJoinedByString:"")
end if
set strHeaderText to ocidHeaderText as text
##############################
#####クエリーの分離
##############################
##NSURL
set ocidURL to refMe's NSURL's URLWithString:(ocidURLString)
##NSURLComponents
set ocidURLComponents to refMe's NSURLComponents's componentsWithURL:(ocidURL) resolvingAgainstBaseURL:(false)
##クエリーの値
set ocidQuery to ocidURLComponents's query()
set strQuery to ocidQuery as text
##クエリーにNULL＝クエリー削除
ocidURLComponents's setQuery:(missing value)
set ocidURL to ocidURLComponents's |URL|()
##############################
##### URL部からファイル名を除く
##############################
set ocidBaseURL to ocidURL's URLByDeletingLastPathComponent()
set strBaseURL to ocidBaseURL's absoluteString() as text
##############################
#####保存先
##############################
##日付時間番号
set ocidDate to refMe's NSDate's |date|()
set ocidNSDateFormatter to refMe's NSDateFormatter's alloc()'s init()
ocidNSDateFormatter's setDateFormat:("yyyyMMddhhmmss")
set ocidDateAndTime to ocidNSDateFormatter's stringFromDate:(ocidDate)
#####保存先のファイルパス
set strTempPath to ("/private/tmp/" & (ocidDateAndTime as text) & "") as text
#####ファイルパス
set ocidDirPath to (refMe's NSString's stringWithString:(strTempPath))
#####フォルダを作っておく
set appFileManager to refMe's NSFileManager's defaultManager()
set ocidAttrDict to refMe's NSMutableDictionary's alloc()'s initWithCapacity:0
ocidAttrDict's setValue:(511) forKey:(refMe's NSFilePosixPermissions)
set listBoolMakeDir to appFileManager's createDirectoryAtPath:(ocidDirPath) withIntermediateDirectories:true attributes:(ocidAttrDict) |error|:(reference)
##############################
##### ダウンロード
##############################
set numCnt to 0 as integer
set numSaveFileNo to 10000 as integer
set numMaxRepeat to 10000
###numMaxRepeatで指定した回数々
repeat numMaxRepeat times
##URL
set numCnt to numCnt + 1 as integer
##ダウンロードするファイル名を連番で整形
set strFileName to ("seg-" & numCnt & "-v1-a1.ts") as text
#ファイル名＋クエリーでURLに
set strURL to (strBaseURL & strFileName & "?" & strQuery) as text
##保存ファイル
set numSaveFileNo to numSaveFileNo + 1 as integer
##ファイル名連番のみ
set strTsFileName to (numSaveFileNo & ".ts")
set strTsDownPath to (strTempPath & "/" & strTsFileName) as text
##コマンド整形
set strCommandText to "/usr/bin/curl '" & strURL & "' -o '" & strTsDownPath & "' " & strHeaderText & "" as text
##コマンド実行
do shell script strCommandText
###ダウンロードしたファイルのファイルサイズを調べる
set ocidDownFilePath to refMe's NSString's stringWithString:(strTsDownPath)
set ocidTsFilePath to ocidDownFilePath's stringByStandardizingPath
set ocidAttributes to appFileManager's attributesOfItemAtPath:(ocidTsFilePath) |error|:(missing value)
set numFileSize to ocidAttributes's NSFileSize as integer
###200b以下ならエラーしたとしてリピート抜けて終了にする
if numFileSize < 200 then
##最後の１コはエラーのHTMLなので削除しておく
##コマンド整形
set strCommandText to "/bin/rm -f '" & strTsDownPath & "'" as text
##コマンド実行
do shell script strCommandText
exit repeat
end if
end repeat
###ダウンロードしたTSファイルを結合して１つのファイルにする
do shell script "cat " & strTempPath & "/* >> ~/Desktop/" & (ocidDateAndTime as text) & ".ts"
return
| 固定リンク
