[PDF化]複数の画像ファイルをPDFにまとめる（解像度を72ppi化）
#!/usr/bin/env osascript
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
#
#
#com.cocolog-nifty.quicktimer.icefloe
----+----1----+----2----+-----3----+----4----+----5----+----6----+----7
##自分環境がos12なので2.8にしているだけです
use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use framework "PDFKit"
use framework "Quartz"
use framework "QuartzCore"
use scripting additions
property refMe : a reference to current application
set appFileManager to refMe's NSFileManager's defaultManager()
#####設定項目 短辺の長さｍｍ
set numShortSize to 210 as integer
###################################
###ポイント換算
set numMaxPtSize to numShortSize * 2.83465 as number
###小数点２桁に(ここは好みの問題)
set numMaxPtSize to ((round (numMaxPtSize * 100) rounding down) / 100) as number
###################################
#####ファイル選択ダイアログ
###################################
###ダイアログのデフォルト
set ocidUserDesktopPath to (appFileManager's URLsForDirectory:(refMe's NSDesktopDirectory) inDomains:(refMe's NSUserDomainMask))
set aliasDefaultLocation to ocidUserDesktopPath as alias
set listChooseFileUTI to {"public.image"}
set strPromptText to "画像ファイルを選んでください" as text
###ダイアログを前面に出す
tell current application
set strName to name as text
end tell
####スクリプトメニューから実行したら
if strName is "osascript" then
tell application "Finder"
activate
set listAliasFilePath to (choose file strPromptText with prompt strPromptText default location (aliasDefaultLocation) of type listChooseFileUTI with multiple selections allowed without invisibles and showing package contents) as list
end tell
else
tell current application
activate
set listAliasFilePath to (choose file strPromptText with prompt strPromptText default location (aliasDefaultLocation) of type listChooseFileUTI with multiple selections allowed without invisibles and showing package contents) as list
end tell
end if
#############################################
##まずはリストをファイル名順にソート
#############################################
###初期化
set ocidFilePathArray to refMe's NSMutableArray's alloc()'s initWithCapacity:0
repeat with itemAliasFilePath in listAliasFilePath
set strFilePath to POSIX path of itemAliasFilePath as text
(ocidFilePathArray's addObject:strFilePath)
end repeat
###ファイルリストをソート
set ocidSortedArray to (ocidFilePathArray's sortedArrayUsingSelector:"compare:")
#############################################
#####保存先 ダイアログ
#############################################
###並び替えたリストの最初のパス
set strFirstFilePath to ocidSortedArray's objectAtIndex:0
set ocidFilePathStr to refMe's NSString's stringWithString:strFirstFilePath
set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
set ocidFilePathURL to refMe's NSURL's alloc()'s initFileURLWithPath:ocidFilePath isDirectory:false
set ocidContainerDirPathURL to ocidFilePathURL's URLByDeletingLastPathComponent()
set aliasDefaultLocation to ocidContainerDirPathURL as alias
####ファイル名を取得
set ocidFileName to ocidContainerDirPathURL's lastPathComponent()
####ファイル名から拡張子を取っていわゆるベースファイル名を取得
set ocidPrefixName to ocidFileName's stringByDeletingPathExtension
###ファイル名
set strPrefixName to ocidPrefixName as text
###拡張子
set strFileExtension to "pdf"
###ダイアログに出すファイル名
set strDefaultName to (strPrefixName & ".image." & strFileExtension) as text
set strPromptText to "名前を決めてください"
set strPromptMes to "名前を決めてください"
###選んだファイルの同階層をデフォルトの場合
#set aliasDefaultLocation to ocidContainerDirPathURL as alias
###選んだファイルの一つ上の階層の場合
set ocidDefaultLocation to ocidContainerDirPathURL's URLByDeletingLastPathComponent()
set aliasDefaultLocation to ocidDefaultLocation as alias
####デスクトップの場合
##set aliasDefaultLocation to (path to desktop folder from user domain) as alias
####ファイル名ダイアログ
####実在しない『はず』なのでas «class furl»で
####スクリプトメニューから実行したら
if strName is "osascript" then
tell application "Finder"
activate
set aliasSaveFilePath to (choose file name strPromptMes default location aliasDefaultLocation default name strDefaultName with prompt strPromptText) as «class furl»
end tell
else
tell current application
activate
set aliasSaveFilePath to (choose file name strPromptMes default location aliasDefaultLocation default name strDefaultName with prompt strPromptText) as «class furl»
end tell
end if
set strSaveFilePath to POSIX path of aliasSaveFilePath as text
set ocidSaveFilePathStr to refMe's NSString's stringWithString:strSaveFilePath
set ocidSaveFilePath to ocidSaveFilePathStr's stringByStandardizingPath()
set ocidContainerSaveDirPath to ocidSaveFilePath's stringByDeletingLastPathComponent()
set ocidSaveFilePathURL to refMe's NSURL's alloc()'s initFileURLWithPath:ocidSaveFilePath isDirectory:false
###拡張子取得
set strFileExtensionName to ocidSaveFilePathURL's pathExtension() as text
###ダイアログで拡張子を取っちゃった時対策
if strFileExtensionName is not strFileExtension then
set ocidSaveFilePathURL to ocidSaveFilePathURL's URLByAppendingPathExtension:strFileExtension
end if
#############################################
####本処理
#############################################
####PDFドキュメント初期化
set ocidActivDoc to refMe's PDFDocument's alloc()'s init()
###画像のファイル数 使わない…画像の数でrepeatするときはこれ
set numCntAllFileNo to (ocidSortedArray count) as integer
###画像のカウンター初期化
set numFileCnt to 0 as integer
###ファイルリストを順番に処理
repeat with itemSortedArray in ocidSortedArray
###########ファイルから
set strFilePath to itemSortedArray as text
set ocidFilePathStr to (refMe's NSString's stringWithString:strFilePath)
set ocidFilePath to ocidFilePathStr's stringByStandardizingPath()
set ocidFilePathURL to (refMe's NSURL's alloc()'s initFileURLWithPath:ocidFilePath isDirectory:false)
###########画像読み込み
set ocidImageData to (refMe's NSImage's alloc()'s initWithContentsOfURL:ocidFilePathURL)
####ピクセルサイズを取得
set ocidImageRepArray to ocidImageData's representations()
set ocidBitmapRep to (ocidImageRepArray's objectAtIndex:0)
set numPixW to ocidBitmapRep's pixelsWide() as integer
set numPixH to ocidBitmapRep's pixelsHigh() as integer
#####サイズをピクセルサイズに設定=72ppi
set ocidNewSize to refMe's NSSize's NSMakeSize(numPixW, numPixH)
(ocidBitmapRep's setSize:ocidNewSize)
##########################################
####新しく↑で作ったサイズで新しいイメージを初期化して
set ocidNewImageData to (refMe's NSImage's alloc()'s initWithSize:ocidNewSize)
####↑このイメージにサイズ変更したNSBitmapImageRepを入れる
(ocidNewImageData's addRepresentation:ocidBitmapRep)
###PDFページに
set ocidPdfPage to (refMe's PDFPage's alloc()'s initWithImage:ocidNewImageData)
###ページに挿入する
(ocidActivDoc's insertPage:ocidPdfPage atIndex:numFileCnt)
####次ページ用にカウントアップ
set numFileCnt to numFileCnt + 1 as integer
set ocidNewImageData to ""
set ocidImageData to ""
set ocidPdfPage to ""
set ocidDistImage to ""
end repeat
####ファイルを保存する
set boolResponse to ocidActivDoc's writeToURL:ocidSaveFilePathURL
####保存先を開く
set appSharedWorkspace to refMe's NSWorkspace's sharedWorkspace()
set boolSelectFileResults to appSharedWorkspace's selectFile:ocidSaveFilePath inFileViewerRootedAtPath:ocidContainerSaveDirPath
| 固定リンク